unity shader之——使用噪声:上篇(消融效果)

很多时候向规则的事物里添加一些“杂乱无章”的效果往往会有意想不到的效果,这些效果的来源就是造成,我们会学习使用噪声来模拟各种看似“神奇”的特效。

一、消融效果

消融效果常见于游戏中角色死亡、地图烧毁等效果。在这些效果中,消融往往从不同的区域开始,并向看似随机的方向扩张,最后整个物体都将消失不见。效果类似如下:


实现原理概况来说就是噪声纹理+透明度测试。我们使用对噪声纹理采样的结果和某个控制消融程度的阈值比较,如果小于阈值,就使用clip函数把他对应的像素裁减掉,这些部分就对应了图中被“烧毁”的区域。而镂空区域边缘的烧焦效果则是将两种颜色混合,再利用pow函数处理后,与原纹理颜色混合后的结果。

1. 声明属性:

Properties {
		_BurnAmount ("Burn Amount", Range(0.0, 1.0)) = 0.0
		_LineWidth("Burn Line Width", Range(0.0, 0.2)) = 0.1
		_MainTex ("Base (RGB)", 2D) = "white" {}
		_BumpMap ("Normal Map", 2D) = "bump" {}
		_BurnFirstColor("Burn First Color", Color) = (1, 0, 0, 1)
		_BurnSecondColor("Burn Second Color", Color) = (1, 0, 0, 1)
		_BurnMap("Burn Map", 2D) = "white"{}
	}

_BurnAmount属性用于控制消融程度,当值为0时,物体为正常效果,为1会完全消融。_LineWidth属性控制模拟烧焦效果时的线宽,它的值越大,火焰边缘的蔓延范围越广。_MainTex和_BumpMap分别对应了物体原本的漫反射纹理和法线纹理,_BurnFirstColor和_BurnSecondColor对应了火焰边缘的两种颜色值。_BumpMap则是噪声纹理。

2. 定义Pass:

Pass {
			Tags { "LightMode"="ForwardBase" }
 
			Cull Off
			
			CGPROGRAM
			
			#include "Lighting.cginc"
			#include "AutoLight.cginc"
			
			#pragma multi_compile_fwdbase

这里使用Cull命令关闭了该shader的面片剔除,也就是说模型的正面和背面都会被渲染,这时因为消融会导致裸露模型内部的构造,如果只渲染正面会出现错误的结果。

3. 定义顶点着色器:

struct v2f {
				float4 pos : SV_POSITION;
				float2 uvMainTex : TEXCOORD0;
				float2 uvBumpMap : TEXCOORD1;
				float2 uvBurnMap : TEXCOORD2;
				float3 lightDir : TEXCOORD3;
				float3 worldPos : TEXCOORD4;
				SHADOW_COORDS(5)
			};
			
			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				
				o.uvMainTex = TRANSFORM_TEX(v.texcoord, _MainTex);
				o.uvBumpMap = TRANSFORM_TEX(v.texcoord, _BumpMap);
				o.uvBurnMap = TRANSFORM_TEX(v.texcoord, _BurnMap);
				
				TANGENT_SPACE_ROTATION;
  				o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;
  				
  				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
  				
  				TRANSFER_SHADOW(o);
				
				return o;
			}

这里把光源方向从模型空间变换到了切线空间。

4. 实现片元着色器来模拟消融效果:

	fixed4 frag(v2f i) : SV_Target {
				fixed3 burn = tex2D(_BurnMap, i.uvBurnMap).rgb;
				
				clip(burn.r - _BurnAmount);
				
				float3 tangentLightDir = normalize(i.lightDir);
				fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap, i.uvBumpMap));
				
				fixed3 albedo = tex2D(_MainTex, i.uvMainTex).rgb;
				
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));
 
				fixed t = 1 - smoothstep(0.0, _LineWidth, burn.r - _BurnAmount);
				fixed3 burnColor = lerp(_BurnFirstColor, _BurnSecondColor, t);
				burnColor = pow(burnColor, 5);
				
				UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
				fixed3 finalColor = lerp(ambient + diffuse * atten, burnColor, t * step(0.0001, _BurnAmount));
				
				return fixed4(finalColor, 1);
			}

首先对噪声纹理采样,将采样结果和用于控制消融程度的属性_BurnAmount相减,传递给clip函数。当结果小于0时,该像素将会被剔除,从而不会显示到屏幕上。如果通过了测试,则进行正常的光照计算。先根据漫反射纹理得到材质的反射率albedo,并由此计算得到环境光照,进而得到漫反射光照。然后计算了烧焦颜色burnColor,我们想要在宽度为_LineWidth的范围内模拟一个烧焦的颜色变化,第一步就使用了smoothstep函数来计算混合系数t。当t值为1时,表明该像素模拟一个烧焦效果。我们首先用t来混合两种火焰颜色_BurnFirstColor和_BurnSecondColor,为了让效果更加接近烧焦的痕迹,我们还使用pow函数对结果进行处理。然后再次使用t来混合正常的光照颜色(环境光+漫反射)和烧焦颜色。我们这里又使用了step函数来保证当_BurnAmount为0时,不显示任何消融效果。最后,返回混合后的颜色值finalColor。

5. 我们还定义了一个用于投射阴影的Pass。使用透明度测试的物体的阴影需要特别处理,如果仍然使用普通的阴影Pass,那么被剔除的区域仍然会向其他物体投射阴影,造成穿帮。为了让物体的阴影也能配合透明度测试产生正确的效果,需要自定义一个阴影投射Pass:

// Pass to render object as a shadow caster
		Pass {
			Tags { "LightMode" = "ShadowCaster" }
			
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag
			
			#pragma multi_compile_shadowcaster
			
			#include "UnityCG.cginc"
			
			fixed _BurnAmount;
			sampler2D _BurnMap;
			float4 _BurnMap_ST;
			
			struct v2f {
				V2F_SHADOW_CASTER;
				float2 uvBurnMap : TEXCOORD1;
			};
			
			v2f vert(appdata_base v) {
				v2f o;
				
				TRANSFER_SHADOW_CASTER_NORMALOFFSET(o)
				
				o.uvBurnMap = TRANSFORM_TEX(v.texcoord, _BurnMap);
				
				return o;
			}
			
			fixed4 frag(v2f i) : SV_Target {
				fixed3 burn = tex2D(_BurnMap, i.uvBurnMap).rgb;
				
				clip(burn.r - _BurnAmount);
				
				SHADOW_CASTER_FRAGMENT(i)
			}
			ENDCG
		}

在unity中,用于投射阴影的Pass的LightMode需要被设置为ShadowCaster,同时还需要使用#pragma_multi_compile_shadowcaster指明它需要的编译指令。

阴影投射的重点在于我们需要按正常Pass的处理来剔除片元或进行顶点动画,以便阴影可以和物体正常渲染的结果相匹配。在自定义阴影投射Pass中,我们通常会使用unity提供的内置宏V2F_SHADOW_CASTER、TRANSFER_SHADOW_CASTER_NORMALOFFSET、SHADOW_CASTER_FRAGMENT来帮助我们计算阴影投射所需要的各种变量,而我们可以只关注自定义计算的部分。上面代码中,首先在v2f结构体中利用V2F_SHADOW_CASTER来定义阴影投射需要定义的变量,随后在顶点着色器中,使用TRANSFER_SHADOW_CASTER_NORMALOFFSET来填充V2F_SHADOW_CASTER在背后声明的一些变量,这里由unity背后为我们完成的。我们需要在顶点着色器中关注自定义的计算部分,这里指的就是我们需要计算噪声纹理的采样结果来剔除片元,最后在利用SHADOW_CASTER_FRAGMENT来让unity为我们完成阴影投射的部分,把结果输出到深度图和阴影映射纹理中。

通过unity提供的三个内置宏(UnityCG.cginc文件中被定义),我们可以方便地自定义需要的阴影投射的Pass,但这些宏需要使用一些特定的输入变量,比如v包含vertex和顶点法线信息等,这里我们使用的内置的appdata_base结构体,它包含了这些必须的顶点变量,如果我们需要进行顶点动画,可以在顶点着色器中直接修改v.vertex,在传递给宏中即可。

使用不同的噪声和纹理属性(即材质面板上纹理的Tiling和Offset值)都会得到不同的消融效果,因此想要得到更好的消融效果,也需要美术人员提供合适的噪声纹理来配合。

版权声明:本文为CSDN博主「小橙子0」的原创文章,
遵循CC 4.0 BY-SA版权协议,转载请附上原文出处链接及本声明。
原文链接:https://blog.csdn.net/cgy56191948/article/details/102873105

最新文章